понедельник, 1 декабря 2008 г.

Вы можете читать контракт и с другой стороны

Это перевод You can read a contract from the other side. Автор: Реймонд Чен. Примечание: в отличие от других постов, этот пост сильно отличается от оригинала. Произведено множество замен от C к Delphi.

Любой интерфейс - это контракт, но помните, что контракт применим к двум сторонам. Чаще всего, когда вы читаете соглашения какого-то интерфейса, вы смотрите на него с точки зрения клиентской стороны (вызывающего), но иногда бывает полезно взглянуть на него и со стороны сервера.

Например, давайте посмотрим на интерфейс для приложений Панели управления.

Чаще всего, когда вы читаете эту документацию, на вас надета кепка "Сейчас я пишу приложение для Панели управления". Поэтому, к примеру, когда в документации написано:
Когда Microsoft Windows в первый раз загружает элемент панели управления, она получает адрес функции CPlApplet и в дальнейшем использует его для вызова функции и передаче ей сообщений.
Когда на вас кепка "Сейчас я пишу приложение для Панели управления", это будет означать: "дьявол, мне лучше бы написать функцию CPlApplet и экспортировать её, чтобы я мог получать сообщения".

Но если вместо этого вы носите кепку "Я пишу замену Панели управления", то это означает: "дьявол, мне лучше бы вызвать GetProcAddress для получения адреса функции CPlApplet, чтобы я мог передавать сообщения".

Аналогично, в секции "Обработка сообщений Панели управления" перечисленны сообщения, которые отправляются от управляющего приложения в приложение панели управления. Если вы носите свою кепку "Сейчас я пишу приложение для Панели управления", то это значит "лучше бы мне быть готовым принять и обработать эти сообщения". Но если вы носите "Я пишу замену Панели управления", то это будет значить: "мне лучше бы отправлять эти сообщения в указанном здесь порядке".

И, наконец, когда документация говорит "управляющее приложение освобождает приложение Панели управления вызовом функции FreeLibrary", ваша кепка "Сейчас я пишу приложение для Панели управления" говорит: "мне лучше бы подготовиться к выгрузке", в то время как ваша "Я пишу замену Панели управления" говорит: "а вот здесь я выгружаю DLL".

Так давайте же попробуем. Начнём с пустого приложения и изменим его FormCreate:
procedure TForm1.FormCreate(Sender: TObject);
var
S: String;
Last: PChar;
C: Integer;
begin
SetLength(S, MAX_PATH);
C := SearchPath(nil, 'access.cpl', nil, Length(S), PChar(S), Last);
if (C > 0) and (C < MAX_PATH) then
begin
Application.ShowMainForm := False;
try
RunControlPanel(S);
finally
Application.Terminate;
end;
end;
end;
Вместо обычного показа окна и входа в цикл сообщений, мы начинаем вести себя, как Панель управления. Сегодняшняя наша жертва: access.cpl (приложение "Специальные возможности"). После нахождения программы на диске, мы просим метод RunControlPanel выполнить всю тяжёлую работу:
uses
JwaWinBase, JwaWinCPL;

...

procedure TForm1.RunControlPanel(const AFileName: String);
var
Act: TACTCTX;
Ctx: THandle;
Cookie: ULONG_PTR;
CPL: HMODULE;
CPlApplet: TCPLApplet;
AppletsCount: Integer;
CPLI: TCPLINFO;
begin
// Может быть, приложение Панели управления имеет свой манифест
FillChar(Act, SizeOf(Act), 0);
Act.cbSize := SizeOf(Act);
Act.dwFlags := 0;
Act.lpSource := PChar(AFileName);
Act.lpResourceName := MAKEINTRESOURCE(123);
Ctx := CreateActCtx(Act);
if (Ctx = INVALID_HANDLE_VALUE) or ActivateActCtx(Ctx, Cookie) then
begin

CPL := SafeLoadLibrary(PChar(AFileName));
if CPL <> 0 then
begin
CPlApplet := GetProcAddress(CPL, 'CPlApplet');
if Assigned(CPlApplet) then
begin
if CPlApplet(Handle, CPL_INIT, 0, 0) <> 0 then
begin
AppletsCount := CPlApplet(Handle, CPL_GETCOUNT, 0, 0);
// Мы собираемся запустить приложение номер ноль
// (В реальной программе мы бы сначала вывели их список пользователю,
// чтобы он выбрал какое-то)
if AppletsCount > 0 then
begin
FillChar(CPLI, SizeOf(CPLI), 0);
CPlApplet(Handle, CPL_INQUIRE, 0, Integer(@CPLI));
CPlApplet(Handle, CPL_DBLCLK, 0, CPLI.lData);
CPlApplet(Handle, CPL_STOP, 0, CPLI.lData);
end;
end;
CPlApplet(Handle, CPL_EXIT, 0, 0);
end;
FreeLibrary(CPL);
end;

if Ctx <> INVALID_HANDLE_VALUE then
begin
DeactivateActCtx(0, Cookie);
ReleaseActCtx(Ctx);
end;
end;
end;
Пока проигнорируйте два блока в начале и в конце, отделённые пустыми строками от центрального кода; мы обсудим их позже.

Всё, что мы делаем - это следуем спецификации, только читаем её со стороны сервера. Поэтому, мы загружаем библиотеку, ищем её точку входа, и вызываем эту точку входа с CPL_INIT, а затем - с CPL_GETCOUNT. Если в этом файле есть приложение Панели управления, то тогда мы получаем информацию о первом апплете, "дважды щёлкаем" на нём (это здесь происходят все интересные вещи), а затем останавливаем его. После всего этого, мы выполняем очистку, согласно правилам (а именно: отправляем сообщение CPL_EXIT).

Вот и всё. Ну, за исключением тех двух блоков кода. Что насчёт них?
Эти два блока кода - поддержка приложений Панели управления, которые имеют свой манифест. Это новая возможность в Windows XP и она документирована в MSDN здесь.

Если вы перейдёте к секции "Using ComCtl32 Version 6 in Control Panel or a DLL That Is Run by RunDll32.exe" ("Использование ComCtl32 версии 6 в Панели управления или в DLL, запускаемой RunDll32.exe"), то вы увидите, что приложение предоставляет Панели управления свой манифест подключением его в виде ресурса с номером 123. Так вот что делает этот код: он загружает и активирует манифест, затем приглашает приложение Панели управления выполнить свою работу (с активным манифестом), потом выполняет очистку. Если манифеста нет, то CreateActCtx возвратит INVALID_HANDLE_VALUE. Мы не считаем это ошибкой, потому что многие программы не имеют манифеста.
Упражнение: какие последствия для безопасности несёт передача nil первым параметром в SearchPath?

Комментариев нет:

Отправить комментарий

Можно использовать некоторые HTML-теги, например:

<b>Жирный</b>
<i>Курсив</i>
<a href="http://www.example.com/">Ссылка</a>

Вам необязательно регистрироваться для комментирования - для этого просто выберите из списка "Анонимный" (для анонимного комментария) или "Имя/URL" (для указания вашего имени и ссылки на сайт). Все прочие варианты потребуют от вас входа в вашу учётку (поддерживается OpenID).

Пожалуйста, по возможности используйте "Имя/URL" вместо "Анонимный". URL можно просто не указывать.

Ваше сообщение может быть помечено как спам спам-фильтром - не волнуйтесь, оно появится после проверки администратором.